home *** CD-ROM | disk | FTP | other *** search
/ Fritz: All Fritz / All Fritz.zip / All Fritz / FILES / EDUCNOMY / ASTROSET.LZH / LUNAR.BAS < prev    next >
BASIC Source File  |  1985-12-20  |  2KB  |  58 lines
  1. 100 REM   COMPUTING LUNAR HEIGHTS
  2. 110 REM
  3. 120 INPUT "HALF-CHORD (MM) ";L1
  4. 130 INPUT "SEGMENT (MM) ";L2
  5. 140 PRINT
  6. 150 PRINT "USE VALUES IN DEGREES"
  7. 160 PRINT
  8. 170 INPUT "EARTH SEL. LONG. ";LE
  9. 180 INPUT "EARTH SEL. LAT. ";BE
  10. 190 INPUT "SUN SEL. COLONG. ";CS
  11. 200 INPUT "SUN SEL. LAT. ";BS
  12. 210 REM  CONVERT DEG TO RADIANS
  13. 220 DR = 3.14159/180
  14. 230 LS = 90-CS
  15. 240 IF LS<0 THEN LS = 450-CS
  16. 250 BE = BE*DR:  LE = LE*DR
  17. 260 BS = BS*DR:  LS = LS*DR
  18. 270 CS = CS*DR
  19. 280 RM = 1080
  20. 290 EM = 239000
  21. 300 SM = 93000000
  22. 310 PRINT
  23. 320 PRINT "ENTER FEATURE DATA"
  24. 330 INPUT "  SEL. LONGITUDE ";LO
  25. 340 INPUT "  SEL. LATITUDE ";BO
  26. 350 INPUT "  SHADOW (MM) ";MQ
  27. 360 BO = BO*DR:  LO = LO*DR
  28. 370 I1 = SIN(BE)*SIN(BO)
  29. 380 I2 = SIN(BE)*SIN(BS)
  30. 390 I3 = SIN(BS)*SIN(BO)
  31. 400 I4 = COS(BE)*COS(BO)
  32. 410 I5 = COS(BE)*COS(BS)
  33. 420 I6 = COS(BS)*COS(BO)
  34. 430 EI = I1+14*COS(LO-LE)
  35. 440 ER = I2+I5*COS(LE-LS)
  36. 450 SI = I3+I6*COS(LO-LS)
  37. 460 RX = L1/SIN(2*ATN(L1/L2))
  38. 470 MR = MQ/RX
  39. 480 I7 = RM*RM:  I8 = EM*EM
  40. 490 I9 = SM*SM
  41. 500 XE = SQR(I7+I8-2*RM*EM*EI)
  42. 510 ES = SQR(I8+I9-2*EM*SM*ER)
  43. 520 XS = SQR(I7+I9-2*RM*SM*SI)
  44. 530 S = (XE+ES+XS)/2
  45. 540 P = S*(S-ES)*(S-XE)*(S-XS)
  46. 550 P = (2/(XE*XS))*SQR(P)
  47. 560 SH = I3+I6*SIN(CS+LO)
  48. 570 M1 = (MR*SH/P)-1
  49. 580 M2 = (MR/P)*((MR/P)-2*SH)
  50. 590 H = (M1+SQR(M1*M1-M2))*RM
  51. 600 H = H*5280: H = INT(H)
  52. 610 PRINT "HEIGHT =";H;" FEET"
  53. 620 PRINT: PRINT "DO ANOTHER ";
  54. 630 PRINT "FROM SAME PHOTO";
  55. 640 INPUT " (Y/N) ";YN$
  56. 650 IF YN$="Y" THEN GOTO 310
  57. 660 END
  58.